/* Rexx --------------------------------------------------------------*/
/* Submit a data set via an IOF server to another system              */
/*                                                                    */
/* From a client IOF session, enter:                                  */
/*   %SVSUB dsn                                                       */
/* to submit the data set "dsn" to server 2 (the default server)      */
/*                                                                    */
/* More examples:                                                     */
/*   %SVSUB MYJOBS.CNTL(TESTIT) SERVER(Y2K)                           */
/*   %SVSUB 'JOE.TEST.JOB' SERVER(TST1) USER(JOE) PW(JOE9999)         */
/*                                                                    */
/* Change the SERVER default name in the model statement below        */
/* if you prefer a different default server.                          */
/*--------------------------------------------------------------------*/

PUSH -1            /*-------------Parm Description-------------------*/,
  "DSN"            /* Data Set Name to submit                        */,
  "SERVER(2)"      /* Name of server                                 */,
  "USER()"         /* Userid if required on server                   */,
  "PW()"           /* Password.  Required only if userid specified.  */,
  "TEST"           /* Trace exec if TEST is specified                */,
                   /*------------------------------------------------*/

parse arg arg_list                /* Process input parms             */
interpret IOFProc(arg_list)       /* Invoke IOFProc to process parms */
if rc > 0 then exit               /* just like clist parms           */
if test = "TEST" then trace 'R'

address TSO
"ALLOC FI(INPUT) DA("DSN") SHR"
"EXECIO * DISKR INPUT (STEM data. finis"
"FREE FI(INPUT)"

address IOF
sparms = 'CMD(*)'
if user \= '' then sparms = sparms 'USER('user pw')'
'SERVER' server sparms ' CLIST'
'JUMP CURRENT'
'TSO ALLOC FILE(READER) SYSOUT(B) WRITER(INTRDR) LRECL(80) RECFM(F)',
  'BLKSIZE(80) REUSE'
'SD $DDNAME$(READER)'
do i = 1 to data.0
  'SNAPTEXT CHAR' data.i
  end
'SNAPCLOS'
'JUMP X'
exit